From c35eb35bb63a97b7c46e879819757a9cb48165b5 Mon Sep 17 00:00:00 2001
From: Thomas Vanbesien <tvanbesi@proton.me>
Date: Tue, 17 Feb 2026 02:27:51 +0100
Subject: Initial commit: OPC UA discovery project

CMake-based C project using open62541 for OPC UA discovery.
Includes Local Discovery Server, register server, and find
servers client with OpenSSL encryption support.
---
 cmake/BuildDeps.cmake | 50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 cmake/BuildDeps.cmake

(limited to 'cmake')

diff --git a/cmake/BuildDeps.cmake b/cmake/BuildDeps.cmake
new file mode 100644
index 0000000..d535e0a
--- /dev/null
+++ b/cmake/BuildDeps.cmake
@@ -0,0 +1,50 @@
+set(OPEN62541_SOURCE_DIR "${CMAKE_SOURCE_DIR}/deps/open62541")
+set(OPEN62541_BUILD_DIR "${CMAKE_BINARY_DIR}/deps/open62541")
+set(OPEN62541_INSTALL_DIR "${CMAKE_BINARY_DIR}/deps/open62541-install")
+
+# --- open62541 ---
+
+if(NOT EXISTS "${OPEN62541_SOURCE_DIR}/CMakeLists.txt")
+  message(
+    FATAL_ERROR
+      "open62541 submodule not initialized. Run: git submodule update --init --recursive"
+  )
+endif()
+
+if(NOT EXISTS "${OPEN62541_INSTALL_DIR}/lib/libopen62541.so")
+
+  message(STATUS "Configuring open62541 in ${OPEN62541_BUILD_DIR}...")
+  set(_cmd
+      ${CMAKE_COMMAND}
+      -S
+      "${OPEN62541_SOURCE_DIR}"
+      -B
+      "${OPEN62541_BUILD_DIR}"
+      -G
+      Ninja
+      -DCMAKE_INSTALL_PREFIX=${OPEN62541_INSTALL_DIR}
+      -DUA_ENABLE_ENCRYPTION=OPENSSL
+      -DUA_ENABLE_DISCOVERY=ON)
+  execute_process(COMMAND ${_cmd} RESULT_VARIABLE _result)
+  if(_result)
+    message(FATAL_ERROR "${_cmd} failed: ${_result}")
+  endif()
+
+  message(STATUS "Building open62541 in ${OPEN62541_BUILD_DIR}...")
+  set(_cmd ${CMAKE_COMMAND} --build "${OPEN62541_BUILD_DIR}" --parallel)
+  execute_process(COMMAND ${_cmd} RESULT_VARIABLE _result)
+  if(_result)
+    message(FATAL_ERROR "${_cmd} failed: ${_result}")
+  endif()
+
+  message(STATUS "Installing open62541 to ${OPEN62541_INSTALL_DIR}...")
+  set(_cmd ${CMAKE_COMMAND} --install "${OPEN62541_BUILD_DIR}")
+  execute_process(COMMAND ${_cmd} RESULT_VARIABLE _result)
+  if(_result)
+    message(FATAL_ERROR "${_cmd} failed: ${_result}")
+  endif()
+else()
+  message(STATUS "open62541 already built, skipping")
+endif()
+
+find_package(open62541 REQUIRED PATHS "${OPEN62541_INSTALL_DIR}" NO_DEFAULT_PATH)
-- 
cgit v1.2.3