# ======================================
# BuildDeps.cmake
# ======================================
#
# Configures, builds, and installs the open62541 library into a local prefix
# under the build tree.  Skips the build when the installed shared library
# already exists.  After installation, open62541 is imported via find_package so
# downstream targets can link against open62541::open62541.

set(OPEN62541_SOURCE_DIR "${CMAKE_SOURCE_DIR}/deps/open62541")
set(OPEN62541_BUILD_DIR "${CMAKE_BINARY_DIR}/deps/open62541")
set(OPEN62541_INSTALL_DIR "${CMAKE_BINARY_DIR}/deps/open62541-install")

if(NOT EXISTS "${OPEN62541_SOURCE_DIR}/CMakeLists.txt")
  message(
    FATAL_ERROR
      "open62541 submodule not initialized. Run: git submodule update --init --recursive"
  )
endif()

if(NOT EXISTS "${OPEN62541_INSTALL_DIR}/lib/libopen62541.so")

  message(STATUS "Configuring open62541 in ${OPEN62541_BUILD_DIR}...")
  set(_cmd
      ${CMAKE_COMMAND}
      -S
      "${OPEN62541_SOURCE_DIR}"
      -B
      "${OPEN62541_BUILD_DIR}"
      -G
      Ninja
      -DCMAKE_INSTALL_PREFIX=${OPEN62541_INSTALL_DIR}
      -DUA_ENABLE_ENCRYPTION=OPENSSL
      -DUA_ENABLE_DISCOVERY=ON)
  execute_process(COMMAND ${_cmd} RESULT_VARIABLE _result)
  if(_result)
    message(FATAL_ERROR "${_cmd} failed: ${_result}")
  endif()

  message(STATUS "Building open62541 in ${OPEN62541_BUILD_DIR}...")
  set(_cmd ${CMAKE_COMMAND} --build "${OPEN62541_BUILD_DIR}" --parallel)
  execute_process(COMMAND ${_cmd} RESULT_VARIABLE _result)
  if(_result)
    message(FATAL_ERROR "${_cmd} failed: ${_result}")
  endif()

  message(STATUS "Installing open62541 to ${OPEN62541_INSTALL_DIR}...")
  set(_cmd ${CMAKE_COMMAND} --install "${OPEN62541_BUILD_DIR}")
  execute_process(COMMAND ${_cmd} RESULT_VARIABLE _result)
  if(_result)
    message(FATAL_ERROR "${_cmd} failed: ${_result}")
  endif()
else()
  message(STATUS "open62541 already built, skipping")
endif()

find_package(open62541 REQUIRED PATHS "${OPEN62541_INSTALL_DIR}"
             NO_DEFAULT_PATH)